Projeção dos últimos 3 meses considerando o último mês projetado

[Johnny Santana]

Pessoal, preciso de um help, preciso calcular o projetado considerando que meu projetado será sempre a média dos últimos 3 meses.

O problema é que quando eu tento fazer este cálculo até funciona no primeiro mês mas nos outros não consigo replicar o mesmo conceito. 

anexo um excel com a fórmula que é o mesmo que preciso replicar no Pbix.

Resultado esperado:

Base.xlsx Projetado dos Ultimos 3 meses.pbix

[Bruno Abdalla de Souza]

Veja se atende @Johnny Santana

Projetado 3M = 
VAR vFaturado = [TotalFaturado]
VAr vDataContexto = 
    MAX(dCalendario[Data])
VAR vAnoMesMaxFaturado = 
    CALCULATE(
        MAX(dCalendario[AnoMesCod]),
        FILTER(
            ALL(dCalendario),
            NOT(ISBLANK([TotalFaturado]))
        )
    )
VAr VMesesProjecao = 
    MAX(dCalendario[AnoMesCod]) - vAnoMesMaxFaturado
VAR vFaturado1M = 
    AVERAGEX(
        FILTER(
            ALL(dCalendario[AnoMesNum], dCalendario[AnoMesNome], dCalendario[AnoMesCod]),
            dCalendario[AnoMesCod] >= vAnoMesMaxFaturado - 2 && 
            dCalendario[AnoMesCod] <= vAnoMesMaxFaturado
        ),
        [TotalFaturado]
    )
VAR vFaturado2M = 
    DIVIDE(
        vFaturado1M + 
        SUMX(
            FILTER(
                ALL(dCalendario[AnoMesNum], dCalendario[AnoMesNome], dCalendario[AnoMesCod]),
                dCalendario[AnoMesCod] >= vAnoMesMaxFaturado - 1 && 
                dCalendario[AnoMesCod] <= vAnoMesMaxFaturado
            ),
            [TotalFaturado]
        ), 
        3
    )
VAR vFaturado3M = 
    DIVIDE(
        vFaturado1M + vFaturado2M +
        CALCULATE(
            [TotalFaturado],
            FILTER(
                ALL(dCalendario[AnoMesNum], dCalendario[AnoMesNome], dCalendario[AnoMesCod]),
                dCalendario[AnoMesCod] = vAnoMesMaxFaturado
            )
        ), 
        3
    )
VAR vFaturado4M = 
    DIVIDE(vFaturado1M + vFaturado2M + vFaturado3M, 3)
VAR vFaturado5M = 
    DIVIDE(vFaturado4M + vFaturado2M + vFaturado3M, 3)
VAR vResultado = 
    IF(
        ISBLANK(vFaturado),
        SWITCH(
            VMesesProjecao,
            1, vFaturado1M,
            2, vFaturado2M,
            3, vFaturado3M,
            4, vFaturado4M,
            5, vFaturado5M
        ),
        vFaturado
    )
RETURN
    vResultado

 

20230110_Projetado dos Ultimos 3 meses.pbix

[Johnny Santana]

Obrigado @Bruno Abdalla de Souza era isso mesmo que eu estava tentando fazer, não no mesmo formato rs mas era esse o resultado esperado, obrigadoo!