Transpor Linha em colunas

[Marcio Monteiro]

Olá pessoal preciso de uma ajudinha gostaria de realizar uma transposição de uma lista em linha para coluna porem separado o numero de contrato no cabeçalho e abaixo do numero do contrato a posição do colaborador.

d48a9237-7006-406c-af4e-127a331523a9.jfif Pasta1.xlsx

[Erick Oliveira]

Boa noite.

Tente esse código em M:

let

    Fonte = Excel.Workbook(File.Contents("C:\Users\erick\Downloads\Pasta1.xlsx"), null, true),

    Tabela1_Table = Fonte{[Item = "Tabela1", Kind = "Table"]}[Data],

    #"Tipo Alterado" = Table.TransformColumnTypes(

        Tabela1_Table, {{"TIPOPERFIL(CUSTOS)", type text}, {"NºCONTRATOS", type text}}

    ),

    #"Linhas Agrupadas" = Table.Group(

        #"Tipo Alterado",

        {"NºCONTRATOS"},

        {{"Table", each _, type table [#"TIPOPERFIL(CUSTOS)" = nullable text, NºCONTRATOS = nullable text]}}

    ),

    #"Table 1" = Table.AddColumn(

        #"Linhas Agrupadas",

        "New Table",

        each

            Table.AddIndexColumn(

                Table.RenameColumns(

                    Table.SelectColumns([Table], "TIPOPERFIL(CUSTOS)"), {"TIPOPERFIL(CUSTOS)", [#"NºCONTRATOS"]}

                ),"Index",1)

    ),

    #"ExpandTable 1" = Table.Combine(#"Table 1"[New Table]),

    #"Linhas Agrupadas1" = Table.Group(#"ExpandTable 1", {"Index"}, {{"Table", each _}}),

    #"Table 2" = Table.AddColumn(

        #"Linhas Agrupadas1",

        "Table 2",

        each

            Table.Distinct(

                Table.FillUp(

                    Table.FillDown([Table], Table.ColumnNames([Table])), Table.ColumnNames([Table])))

    ),

    #"Outras Colunas Removidas" = Table.SelectColumns(#"Table 2", {"Table 2"}),

    #"ExpandTable 2" = Table.Combine(#"Outras Colunas Removidas"[Table 2]),

    #"Colunas Removidas" = Table.RemoveColumns(#"ExpandTable 2", {"Index"})

in

    #"Colunas Removidas"

 

 

[Marcio Monteiro]

BLz meu amigo vou aplicar aqui , Muito obrigado!!