Percentual quando voce se usa ranking e outros

[Divair Zarpelon]

ola pessoal, boa tarde, estou com uma duvida sobre como colocar percentual quando voce usa o ranking.

quero criar uma  matriz mais ou menos conforme a seguir, onde eu mostro os tres maiores fornecedores e todo o resto que tenho a pagar eu coloco em outros

Fornecedor   % A VENCER      A VENCER

A                    9,97%                   300,00

B                   9,31%                    280,00

C                   3,99 %                  120,00

Outros          76,74%             2.309,00

total             100,00%           3.009,00

inicialmente eu criei a medida ranking para ranquear os fornecedores que eu tenho a pagar

ranking = 
RANKX(
    all(FORNECEDOR[Nome Fornecedor]),
    _Medidas[A vencer]
)

apos isso eu coloco todos os fornecedores acima de 3 em outros

A VENCER  = 
IF (
    [ranking] <= 3,
    _Medidas[A vencer],
    IF (
        SELECTEDVALUE ( FORNECEDOR[Nome Fornecedor] ) = "Outros",
        CALCULATE (
            _Medidas[A vencer],
            FILTER (
                ALL ( FORNECEDOR[Nome Fornecedor] ),
                [ranking] > 3
            )
        )
    )
)

minha duvida é como fazer um % dos valores em relacao ao total, ou seja, o fornecedor que é o ranking 1 é x% sobre o total, o 2 é x% e assim na sequencia.
Eu ate consegui fazer isso com os fornecedores porem nao consigui fazer com que o total em outros ficasse com o percentual correto.

Criei a medida 
% sobre total = 
DIVIDE(_Medidas[A vencer],[total a vencer])

sendo que a medida total a vencer é esta
total a vencer = 
CALCULATE(
    _Medidas[A vencer],
    ALLSELECTED('CONTAS PAGAR')
)

tentei fazer dessa forma mais nao deu certo

% A VENCER = 
IF (
    [ranking] <= 3,
    [% sobre total],
    IF (
        SELECTEDVALUE ( FORNECEDOR[Nome Fornecedor] ) = "Outros",
       CALCULATE (
            [% sobre total],
            FILTER (
                ALL ( FORNECEDOR[Nome Fornecedor] ),
                [ranking] > 3)
            )
        )  
       
    )
)

porem o % dos outros fica em 100%, ja os percentuais dos 5 fornecedores fica certo
 

[Rodrigo R1]

@Divair Zarpelon, boa tarde amigo.

Você precisa indicar a solução que lhe atendeu para fechar esse tópico, conforme regras da comunidade. 

Fico feliz que tenha conseguido lhe ajudar. 

[Bruno Abdalla de Souza]

Anexa um exemplo em pbix,.por favor.

[Divair Zarpelon]

ola.. segue o anexo

Arquivo.pbix

[Rodrigo R1]

Boa noite @Divair Zarpelon. Tudo bem, amigo.

Segue a medida para a solução do seu case:

% A VENCER COM RANKING =

IF (

    [ranking] <= SELECTEDVALUE ('Numero Fornecedores'[Numero Fornecedores]),

    [% sobre total],

    IF (

        SELECTEDVALUE ( FORNECEDOR[Nome Fornecedor] ) = "Outros",

       Divide(

           CALCULATE (

        _Medidas[A vencer],

        FILTER (

            ALL ( FORNECEDOR[Nome Fornecedor] ),

            [ranking] > SELECTEDVALUE ('Numero Fornecedores'[Numero Fornecedores])

            )

        ), [total a vencer])  

       

    )

)

Espero que tenha ajudado, amigo.

Sucesso aí....

 

[Bruno Abdalla de Souza]

% A VENCER COM RANKING = 
    VAR vNumForn = MAX ('Numero Fornecedores'[Numero Fornecedores])
    VAR vNomeForn = MAX ( FORNECEDOR[Nome Fornecedor] )
    VAR vRank = [ranking]
RETURN
    IF (
        vRank <= vNumForn,
        [% sobre total],
        IF (
            vNomeForn = "Outros",
            DIVIDE(
                CALCULATE (
                    [A vencer],
                    FILTER(
                        ALL ( FORNECEDOR[Nome Fornecedor] ),
                        [ranking] > vNumForn
                    )
                ),
                [total a vencer]
            )
        )
    )

 

Arquivo.pbix

[Divair Zarpelon]

Voces, os dois...

sao foda...

valeu gurizada......

 

 

Editado Agosto 9, 2022 por Divair Zarpelon

[Divair Zarpelon]

15 minutos atrás, Rodrigo R1 disse:

@Divair Zarpelon, boa tarde amigo.

Você precisa indicar a solução que lhe atendeu para fechar esse tópico, conforme regras da comunidade. 

Fico feliz que tenha conseguido lhe ajudar. 

feito....